ESP32 и Arduino: плата с Wi-Fi на языке скетчей

Технические характеристики ESP32

Главное отличие от классики, о котором забывают чаще всего: логика здесь 3,3-вольтовая. Питать плату по USB можно как обычно, но подавать 5 В на входы нельзя — датчики берите с логикой 3,3 В или ставьте делитель напряжения из двух резисторов.

Распиновка ESP32 DevKit: схема выводов

Схема подходит обычной ESP32 — той, у которой на жестяной крышке модуля написано ESP32-WROOM-32, с буквой на конце или без. Если там ESP32-S3, ESP32-C3 или ESP32-C6, выводы у платы другие: сначала посмотрите, какая ESP32 у вас.

Ниже — самая распространённая учебная плата ESP32 DevKit V1 на 30 контактов, вид сверху: антенна Wi-Fi вверху, micro-USB и кнопки внизу. Наведите на категорию в легенде — её выводы подсветятся. У ESP32, в отличие от Uno и Nano, не все выводы одинаково свободны — зелёные умеют только слушать, а оранжевые не любят нагрузку в момент включения.

Плат ESP32 выпускают десятки видов: на 30, 36 и 38 контактов, с разными разъёмами USB. Номера GPIO у них одинаковые, а порядок на гребёнках бывает разным, так что сверяйтесь с надписями на своей плате. У плат на модуле WROVER выводы 16 и 17 заняты памятью PSRAM.

Распиновки плат на других чипах семейства — на их страницах: распиновка ESP32-C3 Super Mini, ESP32-S3 с модулем N16R8 и ESP32-C6 с Zigbee. Плата ESP32-CAM с камерой собрана на том же чипе, что и DevKit, но почти все её выводы заняты камерой и картой памяти.

Какие выводы можно занимать, а какие — нет

Шпаргалка, которая экономит больше всего нервов при переходе с классических Arduino:

Ещё две тонкости. Во-первых, при включённом Wi-Fi команда analogRead работает только на выводах 32–39: они подключены к первому блоку АЦП (ADC1). Второй блок на время работы сети занят радио. Во-вторых, встроенный светодиод на DevKit висит на выводе 2 — удобно для первых опытов, но помните, что этот же вывод участвует в загрузке.

Шины по умолчанию

• I²C — SDA на выводе 21, SCL на выводе 22: сюда подключаются дисплеи и большинство датчиков (как работает шина I²C).
• SPI — MOSI 23, MISO 19, SCK 18, CS 5: для карт памяти и быстрых дисплеев.
• UART2 — TX 17, RX 16: свободный последовательный порт для GPS, модемов и других плат. На модулях WROVER эти выводы заняты памятью PSRAM.

Как настроить среду для ESP32

Поддержка ESP32 ставится одним пакетом из менеджера плат. В Trema IDE пакет приезжает с российского зеркала за пару минут — без VPN и ручной правки ссылок, которые нужны в классической Arduino IDE. Пошаговая инструкция с экранами — в гайде «ESP32 в Trema IDE». Для платы DevKit V1 в меню выбирайте «DOIT ESP32 DEVKIT V1» — почему не «ESP32 Dev Module», сказано ниже, в разделе про меню плат. Если плата не появилась в списке портов, поставьте драйвер CP2102, CH340 или CH9102.

«Connecting......»: что делать, если прошивка зависла

На этом спотыкаются почти все, кто прошивает ESP32 впервые. Если в консоли после слова Connecting бегут точки, плата не вошла в режим загрузки. Зажмите на плате кнопку BOOT на пару секунд, и прошивка продолжится. На упрямых платах зажмите BOOT ещё до начала загрузки и отпустите, когда она пошла. Плата при этом исправна: так ведёт себя схема автозапуска на дешёвых платах. Другие причины и лечение — в статье «ESP32 не прошивается».

Первая программа: сканер Wi-Fi вместо маячка

Мигать светодиодом ESP32 тоже умеет (он на выводе 2), но для первого раза интереснее то, чего Uno не может: список сетей Wi-Fi вокруг. Скетч ищет их по кругу, с паузой в пять секунд, и печатает имена в монитор порта:

#include <WiFi.h>                  // встроена в пакет ESP32

void setup() {
  Serial.begin(115200);            // монитор порта: скорость 115200
  WiFi.mode(WIFI_STA);             // режим клиента Wi-Fi
}

void loop() {
  int count = WiFi.scanNetworks(); // ищем сети вокруг
  Serial.print("Сетей найдено: ");
  Serial.println(count);
  for (int i = 0; i < count; i++) {
    Serial.println(WiFi.SSID(i));  // имя каждой сети
  }
  delay(5000);                     // повторяем каждые пять секунд
}

Скорость 115200 у ESP32 стандартная. Если в мониторе порта вместо текста «кракозябры», значит, скорость в мониторе не совпадает с той, что в скетче: разбор этой ошибки.

Что делать дальше со связью — разобрано отдельно: как плата подключается к сети (и почему иногда не подключается), страница управления в браузере, умный дом через MQTT и прошивка по воздуху.

ESP32 или классическая Arduino?

Если выбираете между ESP32 и привычной Uno, вот главное:

Простое правило выбора: учиться основам удобнее на Uno или Nano — пятивольтовая логика прощает больше ошибок, а уроков под них море. Как только в проекте появляется слово «интернет», «телефон» или «умный дом», берите ESP32 — какую именно, разобрано ниже. Если плата нужна для первых уроков, загляните в какую плату купить новичку и все платы Arduino в одной таблице.

Какую ESP32 выбрать: сравнение моделей

Словом ESP32 называют две разные вещи. Это первый чип Espressif с Wi-Fi и Bluetooth — тот, которому посвящена эта страница. И это всё семейство, выросшее вокруг него: S2, S3, C3, C6, H2, C5 и P4. В Arduino IDE их поддерживает один пакет ESP32, и скетчи для них пишутся одинаково. А вот умеют чипы разное, и скетч с одной платы не всегда соберётся на другой.

Если коротко:

• Учиться и повторять уроки — обычная ESP32 на плате DevKit. Под неё больше всего готовых скетчей, а классический Bluetooth из всех плат таблицы ниже есть только у неё и у ESP32-CAM: там тот же чип.
• Датчик или реле с Wi-Fi на крошечной плате — ESP32-C3 Super Mini.
• Экран с картинками, камера, голос, USB-клавиатура — ESP32-S3 с модулем N16R8: два ядра и 8 МБ дополнительной памяти PSRAM.
• Умный дом на Zigbee — ESP32-C6: у неё есть радио, на котором работают фабричные датчики и лампы.
• Камера подешевле — ESP32-CAM: та же обычная ESP32, только с камерой и слотом для карты памяти.

Таблица сравнения ESP32, S3, C3, C6 и ESP32-CAM

В столбцах — чипы на тех платах, которые покупают чаще всего. Характеристики взяты из паспортов Espressif, пункты меню — из пакета ESP32 3.3.12. На узком экране таблицу можно прокрутить вбок.

С ESP8266 таблица не сравнивает: это другой чип и другой пакет для Arduino IDE. Она проще и дешевле, а чем ESP8266 отличается от ESP32, разобрано на отдельной странице.

ESP32-S3 или C3

Эти две платы сравнивают чаще всего, хотя они разного класса. У S3 два ядра по 240 МГц, а у ходовой платы N16R8 ещё 8 МБ дополнительной памяти PSRAM: она нужна экранам с картинками и камере. Родной USB у S3 умеет притвориться клавиатурой или флешкой. У C3 одно ядро на 160 МГц и никакой PSRAM, зато Super Mini размером 22,5 на 18 мм и заметно дешевле. Wi-Fi и Bluetooth LE у них одинаковые. Датчику или реле с Wi-Fi хватит C3, экрану и камере нужна S3. Как подключать S3 и почему у неё два разъёма, рассказано в статье ESP32-S3 N16R8: настройки и два USB.

ESP32-C3 или C6

Платы Super Mini на этих чипах внешне почти не отличить, и ядро у них того же типа: одно RISC-V на 160 МГц. Разница в радио. У C6 есть Zigbee и Thread, на которых работают фабричные датчики умного дома, и Wi-Fi 6 — правда, тоже только в диапазоне 2,4 ГГц. Памяти у C6 больше: 512 КБ против 400. Если устройство будет жить в обычной сети Wi-Fi, разница почти незаметна. Если нужен Zigbee, из этих двух подойдёт только C6. Как собрать на ней Zigbee-устройство без хаба, рассказано в отдельной статье. А между S3 и C6 выбирают по задаче: S3 — для тяжёлой графики и камеры, C6 — для умного дома.

Обычная ESP32 или новые S3 и C3

Обычную ESP32 рано списывать. Только у неё есть классический Bluetooth. С ним плата говорит с модулем HC-05 и с телефоном на Android через библиотеку BluetoothSerial и может слать звук в Bluetooth-колонку. С iPhone так не выйдет: там обычным приложениям доступен только Bluetooth LE. ЦАП, настоящий аналоговый выход, тоже есть только у обычной ESP32 и у S2. И под обычную ESP32 написано больше всего уроков. Новые чипы берут ради другого: USB прямо в чипе (переходник и драйвер не нужны), Bluetooth LE 5 вместо 4.2, PSRAM у S3 и Zigbee у C6.

Чип, модуль и плата: что значат WROOM, WROVER и DevKit

Когда говорят «ESP32», имеют в виду одно из трёх: чип, модуль или плату. Чип — квадратная микросхема, то, что делает Espressif. Модуль — маленькая плата, на которой чип и флеш-память спрятаны под жестяную крышку, а рядом медной дорожкой проложена антенна. Название модуля и написано на крышке: ESP32-WROOM-32E или ESP32-S3-WROOM-1. А покупаем мы плату: модуль, разъём USB, кнопки, стабилизатор питания и две гребёнки выводов. DevKit и NodeMCU — названия таких плат. У маленьких плат вроде Super Mini модуля нет: чип с флеш-памятью внутри стоит прямо на плате. Так что вопрос «ESP32 или ESP32-WROOM» не стоит: модуль WROOM-32 и есть обычная ESP32.

У модулей обычной ESP32 несколько поколений. WROOM-32, WROOM-32D и WROOM-32U старые, для новых устройств Espressif их не рекомендует, но работают они так же, и пункт меню у них тот же. Буква U значит, что вместо антенны-дорожки стоит разъём для внешней антенны. WROOM-32E и WROOM-32UE — свежие, с чипом третьей ревизии, в которой исправлены ошибки первых партий. WROVER — модуль подлиннее, в котором кроме флеш-памяти стоит PSRAM, обычно на 8 МБ. Напрямую обычная ESP32 видит из неё только 4 МБ, а выводы 16 и 17 у WROVER заняты этой памятью. Пакет ESP32 находит PSRAM сам, но в меню для WROVER ставят PSRAM: Enabled — так сборка учитывает ошибку кэша старых ревизий чипа, а библиотеки вроде камеры знают, что память есть.

Как узнать, какая ESP32 у вас

Первым делом прочитайте надпись на жестяной крышке модуля. Если крышки нет, как у Super Mini, надпись стоит прямо на чипе. Нажмите на похожую надпись — схема разберёт её по частям:

Если надпись стёрта или её не разглядеть, загрузите в плату любой скетч и посмотрите в окно вывода. Программа загрузки сама называет чип строкой вида Chip type: ESP32-C3 (QFN32) (revision v0.4). А если в меню выбрана плата на другом чипе, загрузка остановится с подсказкой: This chip is ESP32-C3, not ESP32. Это значит, что выбран пункт для обычной ESP32, а на плате C3.

Ещё нагляднее — скетч, который расспрашивает сам чип и печатает ответ в монитор порта: модель, число ядер, объём памяти и какое у чипа радио. Строки про Wi-Fi 6, 5 ГГц и USB он берёт из выбранного пункта меню, остальное читает с чипа при запуске.

// Какая ESP32 на плате: модель, ядра, память, радио и USB.
// Подходит к любой плате семейства в пакете ESP32 версии 3.
// Монитор порта пустой? Если кабель в разъёме, который идёт прямо в чип
// (Super Mini на C3 и C6, разъём USB у S3), включите
// Инструменты -> USB CDC On Boot -> Enabled и загрузите заново.
// Для разъёма COM у S3 этот пункт, наоборот, Disabled.

#include <esp_chip_info.h>

void printHas(const char *name, bool has) {
  Serial.print(name);
  Serial.println(has ? "есть" : "нет");
}

void printInfo() {
  esp_chip_info_t info;
  esp_chip_info(&info);               // что умеет этот чип

  Serial.println();
  Serial.print("Чип: ");
  Serial.println(ESP.getChipModel());

  uint16_t rev = ESP.getChipRevision();  // 301 значит v3.1
  Serial.print("Ревизия: v");
  Serial.print(rev / 100);
  Serial.print(".");
  Serial.println(rev % 100);

  Serial.print("Ядер: ");
  Serial.print(ESP.getChipCores());
  Serial.print(", частота ");
  Serial.print(ESP.getCpuFreqMHz());
  Serial.println(" МГц");

  Serial.print("Флеш-память: ");
  Serial.print(ESP.getFlashChipSize() / (1024 * 1024));
  Serial.println(" МБ");

  // 0, если PSRAM нет. Если есть, число чуть меньше 4096 или 8192:
  // часть памяти занята служебными данными
  Serial.print("PSRAM: ");
  Serial.print(ESP.getPsramSize() / 1024);
  Serial.println(" КБ");

  printHas("Wi-Fi: ", info.features & CHIP_FEATURE_WIFI_BGN);
#if SOC_WIFI_HE_SUPPORT
  Serial.println("Wi-Fi 6: есть");
#endif
#if SOC_WIFI_SUPPORT_5G
  Serial.println("Wi-Fi 5 ГГц: есть");
#endif
  printHas("Классический Bluetooth: ", info.features & CHIP_FEATURE_BT);
  printHas("Bluetooth LE: ", info.features & CHIP_FEATURE_BLE);
  printHas("Zigbee и Thread: ", info.features & CHIP_FEATURE_IEEE802154);
#if CONFIG_ESP_HOSTED_ENABLED
  Serial.println("Wi-Fi и Bluetooth через второй чип на плате");
#endif

  Serial.print("USB: ");
#if SOC_USB_OTG_SUPPORTED
  Serial.println("в чипе, может быть клавиатурой (у S3 - с USB Mode: USB-OTG)");
#elif SOC_USB_SERIAL_JTAG_SUPPORTED
  Serial.println("в чипе, только порт и прошивка");
#else
  Serial.println("через микросхему-переходник на плате");
#endif
}

void setup() {
  Serial.begin(115200);
}

void loop() {
  printInfo();                        // повторяем: монитор успеет подключиться
  delay(10000);
}

Скетч проверен сборкой на всех пяти платах из таблицы, с теми пунктами меню, что в ней указаны. Печатает он раз в десять секунд: у плат с родным USB монитор порта подключается не сразу после загрузки. PSRAM у S3 скетч покажет нулём, если она выключена в меню или выбран не тот её тип, — удобная проверка настроек N16R8. У обычной ESP32 с модулем WROVER будет около 4 МБ.

Что выбрать в меню плат Arduino IDE

Пункт меню отвечает за три вещи: под какой чип собирается программа, какие выводы стоят за именами вроде LED_BUILTIN и SDA и куда пойдёт Serial. Ошибку с чипом вы заметите сразу: загрузка просто не начнётся. А вот с выводами и монитором порта ошибка тихая: всё загрузилось, а светодиод не мигает и монитор молчит. Поэтому для ходовых плат в таблице выше стоит конкретный пункт, а не «Dev Module» для всех.

С обычной ESP32 чаще всего не собирается пример Blink: под «ESP32 Dev Module» сборка падает с ошибкой 'LED_BUILTIN' was not declared in this scope, потому что у разных плат светодиод на разных выводах. Выберите «DOIT ESP32 DEVKIT V1» или «NodeMCU-32S»: у обоих LED_BUILTIN — вывод 2. У плат на S3, C3 и C6 своя беда: Serial уходит не в тот USB. Если кабель в разъёме, который идёт прямо в чип, а USB CDC On Boot выключен, монитор порта молчит. У S3 с двумя разъёмами для разъёма COM этот пункт, наоборот, выключают. Подробности — в статьях почему у C3 молчит монитор порта и к какому из двух USB подключать ESP32-S3.

Что перестанет работать при переходе с обычной ESP32

Большинство скетчей переносятся между чипами без правок: digitalWrite, Wi-Fi, датчики по I²C. Но то, что завязано на особое железо, на другой ESP32 не соберётся. Ниже — что встречается в уроках чаще всего. Ошибки сняты настоящими сборками в пакете ESP32 3.3.12.

Последняя строка коварнее остальных: сборка проходит, а датчик показывает 0 у обычной ESP32 или 65535 у S3. Второй блок АЦП (ADC2) занят радио, пока работает Wi-Fi, и analogRead об этом не сообщает. У C3 второй блок не работает вовсе, даже без Wi-Fi.

ESP32-S2, H2, C5 и P4 — коротко

• ESP32-S2 — одно ядро на 240 МГц, Wi-Fi и родной USB, который умеет быть клавиатурой и флешкой. Bluetooth у S2 нет совсем. Есть ЦАП на выводах 17 и 18 и сенсорные входы. Ходовая плата — S2 Mini, в меню «LOLIN S2 Mini».
• ESP32-H2 — без Wi-Fi: только Bluetooth LE и Zigbee с Thread, ядро на 96 МГц. Чип для батарейных датчиков. Скетч с библиотекой WiFi на нём не соберётся: 'WiFi' was not declared in this scope.
• ESP32-C5 — единственный в семействе с Wi-Fi в диапазоне 5 ГГц: Wi-Fi 6 в обоих диапазонах, плюс Bluetooth LE, Zigbee и Thread, одно ядро на 240 МГц. В пакете ESP32 он есть с версии 3.3.0, плат пока десять.
• ESP32-P4 — самый быстрый: два ядра до 400 МГц, для больших экранов и камер. Своего радио у него нет. На большинстве плат с P4 рядом стоит ESP32-C6 со своей прошивкой, и Wi-Fi с Bluetooth работают через неё. Нет второго чипа — нет и беспроводной связи.

В пакете ESP32 3.3.12 есть ещё пункты ESP32-C2 и ESP32-C61, но они скрыты: библиотек для этих чипов в пакет не положили, и из Arduino IDE их не собрать.

Что собирают на ESP32

• Метеостанция с веб-страницей — датчики меряют, плата раздаёт результаты прямо в браузер телефона.
• Умные розетки и свет — управление реле по Wi-Fi из дома или дачи.
• Датчики с уведомлениями — протечка, открытая дверь, температура теплицы: плата сама шлёт сообщение.
• Bluetooth-проекты — пульты, датчики и обмен данными с телефоном без всякой сети.
• Обычная автоматика — и без сети: ESP32 быстрее Uno, памяти у неё в сотни раз больше, а ШИМ есть почти на любом выводе.