ESP32-C3 Super Mini: распиновка, характеристики и прошивка

Характеристики ESP32-C3 Super Mini

По скорости одно ядро C3 на 160 МГц примерно равно одному ядру классической ESP32: Espressif даёт им 483 и 540 баллов в тесте CoreMark. Только у классической ядер два. Для датчика с отправкой показаний, реле по Wi-Fi или кнопки на Bluetooth этого хватает с запасом.

Главное, что нужно помнить с первой минуты: логика у платы 3,3-вольтовая. По паспорту чипа на вход можно подать не больше 3,6 В, поэтому сигнал от пятивольтовой Arduino или датчика подключают через делитель из двух резисторов или преобразователь уровней.

Распиновка ESP32-C3 Super Mini

У платы две гребёнки по восемь контактов. С одной стороны — питание и выводы 0–4, с другой — выводы 5–10, 20 и 21. Наведите на категорию в легенде, чтобы подсветить её выводы, и нажмите на неё, чтобы прочитать пояснение. Синий светодиод на схеме мигает так же, как в первом примере ниже.

Почему на картинках из интернета всё наоборот

Одна из самых распространённых картинок распиновки нарисована с обратной стороны платы — той, где напечатано «ESP32-C3 Super Mini». На ней 5V, GND и 3V3 слева. Но плату обычно держат деталями вверх, видя кнопки и антенну, и тогда питание оказывается справа. Отсюда классическая ошибка: провод уходит на соседний ряд, и плата не отзывается. Переключатель над схемой показывает обе стороны; надёжнее всего ориентироваться по подписям «5V», «G» и «3.3» у контактов.

Какие выводы можно занимать

Пины запуска опасны не сами по себе. Чип смотрит на выводы 2, 8 и 9 только в момент включения или сброса кнопкой RST, а потом ими можно пользоваться как обычными. Беда случается, если к ним подключено что-то, что в этот момент тянет вывод не туда: кнопка на землю, датчик с подтяжкой вниз, модуль, который при включении держит линию в нуле.

Шины по умолчанию

• I²C — SDA на выводе 8, SCL на выводе 9. Оба вывода уже подтянуты к плюсу на плате, так что дисплей и датчики работают сразу. Синий светодиод при этом подмигивает в такт обмену — это нормально. Разбор шины — в статье про I²C.
• SPI — SCK 4, MISO 5, MOSI 6, SS 7: для карт памяти и быстрых дисплеев.
• UART — у C3 два аппаратных порта: UART0 на выводах 20 и 21 и UART1. Serial у Super Mini идёт через USB, а порт Serial1 можно вывести на любые свободные выводы: Serial1.begin(9600, SERIAL_8N1, 3, 4); — приём на 3, передача на 4. Подробнее — про UART.

Шины у C3 не привязаны к выводам намертво: если 8 и 9 заняты, назначьте I²C на другие свободные выводы командой Wire.begin(sda, scl). На заводской схеме платы I²C подписан на выводах 4 и 5 — если на 8 и 9 мешают светодиод и кнопка BOOT, подключайте шину туда: Wire.begin(4, 5).

Какую плату выбрать в Arduino IDE и Trema IDE

Это главный вопрос всей статьи. В пакете ESP32 подходящих пунктов несколько, и все они собирают программу без ошибок. Разница проявляется уже на плате: в одних вариантах монитор порта молчит, в других не мигает светодиод. Переключайте варианты на схеме:

Правильный выбор — «Nologo ESP32C3 Super Mini» в семействе ESP32. В нём вывод в монитор порта через USB включён всегда, а LED_BUILTIN — это вывод 8, где и стоит синий светодиод. Этот пункт есть в пакете ESP32 3.x. В старом пакете 2.0.17 его ещё не было, и многие инструкции советуют «ESP32C3 Dev Module». С ним нужно сделать две вещи: включить параметр USB CDC On Boot и писать в скетчах номер 8 вместо LED_BUILTIN. В Arduino IDE параметр находится в меню «Инструменты», в Trema IDE — за кнопкой «Параметры платы» на верхней панели. Названия пунктов в обеих средах одинаковые: их задаёт сам пакет.

Пакет ставится один раз через менеджер плат. Как это сделать по шагам и что делать, если у Arduino IDE не скачивается список пакетов, — в инструкции «ESP32 в Trema IDE» и в статье про ошибку 403.

Первая прошивка: мигаем синим светодиодом

1. Подключите плату кабелем USB-C. Кабель должен передавать данные: короткие шнурки «только для зарядки» плату питают, но порта не дают.
2. Выберите плату «Nologo ESP32C3 Super Mini» и появившийся порт.
3. Вставьте скетч и нажмите «Загрузить».

// Синий светодиод ESP32-C3 Super Mini подключён к выводу 8
// «наоборот»: горит, когда на выводе LOW, и гаснет от HIGH.
const int LED_PIN = 8;

void setup() {
  Serial.begin(115200);         // порт USB у этой платы: скорость ни на что не влияет
  pinMode(LED_PIN, OUTPUT);
}

void loop() {
  digitalWrite(LED_PIN, LOW);   // LOW — светодиод загорается
  Serial.println("Светодиод горит");
  delay(500);

  digitalWrite(LED_PIN, HIGH);  // HIGH — гаснет
  Serial.println("Светодиод погас");
  delay(500);
}

Обратите внимание на LOW и HIGH. На плате синий светодиод включён между плюсом и выводом 8, поэтому он загорается, когда вывод опускается в ноль. Если перепутать, программа будет работать «наоборот» — светодиод горит, когда должен гаснуть.

Драйвер ставить не нужно. На плате нет отдельной микросхемы USB вроде CH340 или CP2102: USB сделан самим чипом и представляется компьютеру стандартным последовательным портом. Для таких устройств Windows 10 и 11 ставят драйвер сами. Поэтому драйвер CH340, который часто советуют, здесь ничего не изменит. Если порт не появился, чаще всего дело в кабеле или разъёме — как это проверить. Если кабель точно передаёт данные, переведите плату в режим прошивки вручную, как описано ниже.

В Диспетчере устройств рядом с портом может появиться «USB JTAG/serial debug unit» с жёлтым значком. Это интерфейс отладки: для загрузки программ и монитора порта он не нужен, и драйвер для него ставить не обязательно.

Если загрузка не идёт: «Failed to connect to ESP32-C3»

Обычно среда сама переводит плату в режим прошивки по USB. Но если загруженная раньше программа уводит плату в сон, падает сразу после старта или занимает выводы USB, связаться с чипом не получится. Тогда в журнале загрузки будет:

A fatal error occurred: Failed to connect to ESP32-C3: No serial data received.

Лечится это ручным входом в режим прошивки. Пройдите шаги на схеме — кнопки нарисованы так же, как стоят на плате:

Другая частая ошибка — выбрана не та плата. Если в меню стоит обычная ESP32, а подключена C3, загрузчик скажет об этом прямо:

This chip is ESP32-C3, not ESP32. Wrong chip argument?

Значит, нужно выбрать плату на C3. Остальные причины неудачной загрузки общие для всех ESP32 и разобраны в статье «ESP32 не прошивается».

Монитор порта молчит

Программа загрузилась, а в мониторе порта пусто. Причин три.

• Выбрана «ESP32C3 Dev Module» без USB CDC On Boot. Тогда Serial пишет не в USB, а в выводы 20 и 21. Включите параметр или выберите «Nologo ESP32C3 Super Mini».
• Текст ушёл раньше, чем открылся монитор. После загрузки плата перезапускается, и компьютер заново подключает её порт. Строки, напечатанные в setup() в эти мгновения, могут не дойти до монитора. Добавьте в начало setup() задержку на полторы-две секунды или печатайте в loop().
• Плата уснула или перезапускается. В глубоком сне USB отключается совсем, и порт пропадает у компьютера до пробуждения. Если же плата перезапускается по кругу, порт мелькает и исчезает. Тогда проверьте питание — подробности ниже.

А вот кракозябр из-за скорости здесь не бывает. Число в Serial.begin() и в мониторе порта для USB этой платы ни на что не влияет: данные идут пакетами USB, а не по проводу с заданной скоростью. Скорость важна только для Serial1 и переходников на выводах 20 и 21.

Аналоговые входы: пять, а не шесть

На распиновках вывод 5 часто подписан A5, и в описании платы в пакете он тоже числится A5. Но работать аналоговым входом он не будет: на нём единственный канал второго аналого-цифрового преобразователя, а работу с этим преобразователем у ESP32-C3 пакет отключает. Документация Espressif объясняет: режим больше не поддерживается из-за аппаратных ограничений, результаты нестабильны. analogRead(5) вернёт ноль. Для аналоговых датчиков остаются выводы 0–4.

Второе отличие от Uno — диапазон. analogRead() возвращает число от 0 до 4095, а точно чип меряет напряжения только до 2,5 В. Это видно на простом опыте с потенциометром:

// Потенциометр на выводе 0 (он же A0). Крайние ножки потенциометра —
// на 3V3 и GND, средняя — на вывод 0. Аналоговые входы платы: 0, 1, 2, 3, 4.
const int POT_PIN = 0;

void setup() {
  Serial.begin(115200);
}

void loop() {
  int raw = analogRead(POT_PIN);           // число от 0 до 4095
  int mv = analogReadMilliVolts(POT_PIN);  // то же самое в милливольтах
  Serial.print(raw);
  Serial.print("  ");
  Serial.print(mv);
  Serial.println(" мВ");
  delay(300);
}

analogReadMilliVolts() сразу пересчитывает показания в милливольты по заводской калибровке чипа. Ею удобнее пользоваться, чем самому делить на 4095: зависимость у преобразователя не совсем прямая. Точность ±35 мВ из паспорта чипа — как раз про неё. Сырое число analogRead() у разных экземпляров чипа отличается заметнее.

Wi-Fi: если плата не подключается к сети

Сначала обычные причины. C3 работает только в диапазоне 2,4 ГГц, и к сети 5 ГГц не подключится никогда. Если у роутера одно имя на оба диапазона, иногда помогает развести их на два имени. Пароль чувствителен к регистру.

Дальше — особенность именно Super Mini. На форумах много сообщений о партиях, где плата видит сеть, но не может к ней подключиться или постоянно отваливается. Чаще всего винят разводку: керамическая антенна стоит слишком близко к кварцу. Обходной приём, который советуют чаще всего и который многим помогает, — снизить мощность передатчика до 8,5 dBm. Связь становится короче, зато устойчивее. Если и это не спасает, остаётся плата с внешней антенной.

#include <WiFi.h>

const char* WIFI_NAME = "имя_вашей_сети";   // только сеть 2,4 ГГц
const char* WIFI_PASS = "пароль";

void setup() {
  Serial.begin(115200);
  delay(1500);                     // время открыть монитор порта

  WiFi.STA.begin();                // включаем Wi-Fi, но пока не подключаемся
  // Мощность меняется только у включённого Wi-Fi: до STA.begin()
  // или до WiFi.begin() команда вернёт false и ничего не сделает.
  if (WiFi.setTxPower(WIFI_POWER_8_5dBm)) {
    Serial.println("Мощность передатчика снижена до 8,5 dBm");
  }
  WiFi.begin(WIFI_NAME, WIFI_PASS);

  Serial.print("Подключаюсь");
  unsigned long start = millis();
  while (WiFi.status() != WL_CONNECTED && millis() - start < 20000) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  if (WiFi.status() == WL_CONNECTED) {
    Serial.print("Готово, адрес платы: ");
    Serial.println(WiFi.localIP());
    Serial.print("Мощность, четверти dBm: ");
    Serial.println(WiFi.getTxPower());   // 34 = 8,5 dBm: снижение сработало
  } else {
    Serial.println("Не подключилась: проверьте имя сети и пароль");
  }
}

void loop() {
  if (WiFi.status() == WL_CONNECTED) {
    Serial.print("Сигнал: ");
    Serial.print(WiFi.RSSI());     // чем ближе к нулю, тем лучше
    Serial.println(" dBm");
  }
  delay(5000);
}

Важна последовательность. Мощность можно поменять только у уже включённого Wi-Fi. Если вызвать WiFi.setTxPower() до WiFi.STA.begin() или WiFi.begin(), команда вернёт false и ничего не сделает. Поэтому в скетче Wi-Fi сначала включается, потом снижается мощность, и только после этого плата подключается к сети. Строка «Мощность» в мониторе порта показывает, что снижение сработало: число там в четвертях децибела, и 34 — это 8,5 dBm. Число RSSI показывает уровень сигнала: −50 dBm — отлично, −80 — на грани.

Если не помогло — попробуйте другой источник питания. На пике передачи чип берёт до 335 мА, и слабый USB-порт или длинный тонкий кабель проседают именно в этот момент. Что делать с подключённой платой дальше — в серии про Wi-Fi: веб-страница на плате, умный дом через MQTT, прошивка по воздуху.

Питание: USB, вывод 5V, 3V3 и аккумулятор

По опубликованной схеме платы всё просто: пять вольт с разъёма проходят через диод на стабилизатор ME6211, тот делает 3,3 В для чипа. Но есть одна особенность разводки, о которой стоит знать до того, как подключать внешний блок. Выберите способ питания:

Бюджет тока такой. Стабилизатор отдаёт до 500 мА, из них на пиках передачи до 335 мА забирает сам чип. На датчики и модули с вывода 3V3 остаётся около 150 мА в пике, а постоянно лучше брать не больше 100 мА: крошечный стабилизатор заметно греется. Сервопривод, светодиодную ленту или мотор от 3V3 не питайте: им нужен свой источник, общий с платой только по земле.

Для работы от батарей есть ещё одна деталь. Сам чип в глубоком сне потребляет около 5 мкА, но на плате всегда горит красный светодиод питания и работает стабилизатор. Один светодиод берёт около половины миллиампера — примерно в сто раз больше, чем спящий чип. Для долгой работы от батареек светодиод питания выпаивают или берут плату без него. Подробнее о вариантах питания — в статье про питание.

Место под программу: Wi-Fi занимает почти всё

Флеш-памяти у платы 4 МБ, но под программу по умолчанию отведено 1,25 МБ. Остальное занимают запасное место для обновления по воздуху и файловая система. Wi-Fi и Bluetooth тянут за собой много кода, и это место заканчивается быстрее, чем кажется:

Когда программа не помещается, сборка останавливается с сообщением:

Скетч использует 1368457 байт (104%) памяти устройства. Всего доступно 1310720 байт.
Скетч слишком большой; прочитайте https://support.arduino.cc/hc/en-us/articles/360013825179
Ошибка во время сборки: секция текста превышает доступное пространство на плате

Выход — другая разметка памяти. В параметре Partition Scheme выберите «Huge APP (3MB No OTA/1MB SPIFFS)»: под программу будет 3 МБ. Цена — обновлять программу по Wi-Fi станет нельзя, только по кабелю. Если обновление по воздуху нужно, ищите, какую библиотеку можно выбросить. В Trema IDE на эту ошибку выходит карточка «Программа не помещается в память платы» с тем же советом.

Чего у ESP32-C3 нет

C3 — упрощённый родственник классической ESP32, и часть привычных примеров на ней не соберётся. Сборка под ESP32-C3 отвечает так:

Если проекту нужно что-то из этого списка, берите классическую ESP32. Сенсорные входы, а ещё PSRAM и родной USB для клавиатуры есть у ESP32-S3. А связаться с телефоном по Bluetooth LE C3 умеет: для этого есть библиотека BLE, встроенная в пакет. Классический модуль HC-05 и его отличия от BLE разобраны в статье про Bluetooth.

Super Mini, XIAO ESP32-C3 или обычная ESP32

Super Mini берут за размер и цену. XIAO ESP32-C3 от Seeed Studio того же размера, но с зарядкой литиевого аккумулятора и внешней антенной в комплекте — для носимых устройств и датчиков на батарее это заметно удобнее. У XIAO другие подписи выводов (D0–D10), и в меню для неё есть свой пункт «XIAO_ESP32C3». В магазине iarduino XIAO ESP32-C3 есть в наличии: 960 ₽, артикул 1792. Когда нужны память, камера или USB-клавиатура, берут ESP32-S3, а камеру дешевле всего поставить на ESP32-CAM. Для Zigbee и Wi-Fi 6 есть ESP32-C6, и её Super Mini внешне почти не отличить от C3. Когда выводов или классического Bluetooth не хватает, остаётся обычная ESP32 — справочник ESP32 DevKit. А если ESP32 ещё рано и нужно сначала научиться основам, удобнее начать с Arduino Uno и уроков для начинающих.