ESP32 · LittleFS · Trema IDE

Файлы на ESP32: папка data и LittleFS

В памяти ESP32 можно держать не только программу, но и файлы: страницу сайта, картинки, настройки. Кладёте их в папку data рядом со скетчем и нажимаете «Файлы» — они переезжают в плату, а скетч читает их как с флешки. Ниже — весь путь в Trema IDE по шагам, два готовых скетча и что делать, если не выходит.

Короче некуда. «Параметры платы» → схема памяти с местом под файлы → подключить плату кабелем и выбрать её порт → залить скетч кнопкой «Загрузить» → «Файлы» → «Создать папку data» → положить в неё файлы → «Файлы» → «Залить». Кнопка «Файлы» есть в Trema IDE начиная с версии 1.10.13.

Зачем плате файлы

У ESP32 обычно 4 МБ флеш-памяти, а программе из них достаётся чуть больше одного. Остальное можно отдать под файлы — как маленькую флешку прямо внутри платы. Что туда кладут:

  • Страницы сайта — index.html, стили, скрипты, значок. Плата раздаёт их в браузер, а вы правите страницу в обычном редакторе, а не строчками внутри скетча.
  • Картинки и шрифты для экрана или для той же страницы.
  • Настройки — например config.json с именем устройства и интервалом опроса датчика. Поменяли файл — поменялось поведение, а программу перезаливать не нужно.
  • Звуки и тексты — короткие записи, словари, таблицы.

Главное удобство: файлы и программа живут отдельно. Переделали оформление страницы — залили только файлы. Исправили программу — залили только скетч, файлы на месте (если в «Параметрах платы» не включено «Erase All Flash Before Sketch Upload» → Enabled: оно стирает перед скетчем всю память, файлы тоже).

LittleFS и SPIFFS: что это

Файловая система — порядок, в котором файлы разложены по памяти. Trema IDE заливает файлы в LittleFS, и скетч читает их через #include <LittleFS.h>. Раздел памяти под файлы по старой памяти называется spiffs — по имени прежней файловой системы, — но внутри у него LittleFS.

Важно: в скетче LittleFS, не SPIFFS. Со SPIFFS.begin(true) плата не узнает файлы LittleFS, сочтёт раздел испорченным и отформатирует его — всё залитое пропадёт.

Что понадобится

  • Плата на ESP32 — обычная ESP32, C3, S3 или C6 — и кабель USB, который передаёт данные, а не только заряжает. Файлы заливаются только по кабелю.
  • Trema IDE 1.10.13 или новее: в ранних версиях кнопки «Файлы» нет.
  • Пакет плат ESP32 — он ставится сам, когда выбираете плату. В нём же лежат программы, которые упаковывают и записывают файлы, отдельно ничего скачивать не нужно.

Шаг 1. Выберите плату и схему памяти

Память платы поделена на разделы: один под программу, другой под файлы. Как именно поделена, задаёт схема памяти — Partition Scheme. Таблицу этих разделов Trema IDE называет разметкой памяти: это слово будет в окнах программы.

Выберите свою плату вверху окна, например «ESP32 Dev Module». Не знаете, какая у вас, — посмотрите в статье «ESP32 в Arduino IDE»; большинству плат с надписью WROOM подходит ESP32 Dev Module. Справа от названия платы — кнопка с ползунками, «Параметры платы». Там пункт Partition Scheme: он решает, сколько памяти получит программа, а сколько файлы. Для ESP32 Dev Module и большинства плат с 4 МБ:

Partition SchemeПрограммеФайламКогда брать
Default 4MB with spiffs (1.2MB APP/1.5MB SPIFFS)1,25 МБ1,4 МБВыбрана сразу. Скетч можно заливать и по Wi-Fi
Huge APP (3MB No OTA/1MB SPIFFS)3 МБ896 КБДля большой программы. По Wi-Fi скетч не залить
No OTA (2MB APP/2MB SPIFFS)2 МБ1,9 МБПоровну программе и файлам. По Wi-Fi скетч не залить
No OTA (1MB APP/3MB SPIFFS)1 МБ2,9 МББольше всего места под файлы. По Wi-Fi скетч не залить
Minimal SPIFFS (1.9MB APP with OTA/128KB SPIFFS)1,9 МБ128 КБХватит на страницу и настройки, не на картинки
No FS 4MB (2MB APP x2)1,9 МБнетКнопка «Файлы» откажется: места под файлы нет
Default 4MB with ffat (1.2MB APP/1.5MB FATFS)1,25 МБнетРаздел под другую файловую систему (FAT) — для кнопки «Файлы» не подходит

Цифры в названиях схем приблизительные, в таблице — настоящие размеры разделов из пакета плат ESP32 3.3.12. Если не знаете, что выбрать, оставьте Default: 1,4 МБ хватит на сайт из нескольких страниц с картинками. Под «Файлам» — весь раздел, на деле файлам достаётся чуть меньше: часть уходит на служебные записи файловой системы. У плат с 8 или 16 МБ (часто это S3) свои схемы: выбирайте ту, где в скобках после «/» есть SPIFFS, например «8M with spiffs (3MB APP/1.5MB SPIFFS)».

Бывает, что разметку задаёт не меню. Если в папке проекта лежит свой файл partitions.csv, главнее он; у некоторых плат свой файл разметки зашит в описание платы. Trema IDE берёт разметку в том же порядке, что и сборка скетча, так что скетч и файлы всегда смотрят в одну и ту же схему.

Шаг 2. Залейте скетч с этой схемой

Подключите плату кабелем, выберите её порт вверху окна и нажмите «Загрузить». Подойдёт любой скетч, даже пустой из нового проекта: сейчас важна только схема памяти. Можно сразу залить пример 1 ниже.

Это важно сделать до файлов: разметка памяти — таблица «где программа, где файлы» — записывается в плату вместе со скетчем. Кнопка «Файлы» пишет туда, где раздел для файлов в выбранной сейчас схеме. Перед записью Trema IDE читает таблицу с самой платы и сверяет: если скетч залит с другой схемой, она откажется и ничего не тронет, иначе файлы легли бы поверх программы.

Отсюда правило: сменили Partition Scheme — сначала «Загрузить», потом «Файлы». Об этом же напоминает строка в окне подтверждения.

Шаг 3. Нажмите «Файлы» и создайте папку data

У проектов на ESP32 и ESP8266 на панели сразу за «Загрузить» есть кнопка «Файлы». В Trema IDE кнопка пока есть только у плат ESP32 и ESP8266.

Верхняя панель Trema IDE: кнопка «Параметры платы» с ползунками, порт COM4, кнопки «Проверить», «Загрузить» и справа «Файлы»
Слева направо: «Параметры платы» (ползунки), порт, «Проверить», «Загрузить» и «Файлы».

Пока папки data нет, кнопка ничего не заливает, а объясняет, что к чему. Откроется окно «Файлы на плате» с тремя кнопками: «Закрыть», «Как это работает» (ведёт на эту страницу) и «Создать папку data».

Окно Trema IDE «Файлы на плате»: ESP32 и ESP8266 умеют хранить файлы, положите их в папку data и нажмите «Файлы», скетч читает их через LittleFS; кнопки «Закрыть», «Как это работает», «Создать папку data»
Окно «Файлы на плате» — когда папки data ещё нет.

Нажмите «Создать папку data». Папка появится рядом со скетчем и в списке файлов проекта и сразу откроется в файловом менеджере (в Windows — в Проводнике): перетащите файлы туда. В консоли — строка «Папка data создана рядом со скетчем. Положите в неё файлы для платы и нажмите «Файлы»». Если папка уже есть, но пустая, на этом месте будет кнопка «Открыть папку data»: она откроет папку в файловом менеджере.

Шаг 4. Положите файлы в data

Скопируйте в папку всё, что должно оказаться на плате. Для примеров ниже нужны три файла:

FsEsp32/
├── FsEsp32.ino      ← скетч, в плату не попадает как файл
└── data/
    ├── config.json  → на плате /config.json
    ├── index.html   → на плате /index.html
    └── style.css    → на плате /style.css

Сама папка data в имя не входит: файл data/index.html на плате называется /index.html, а data/img/cat.png — /img/cat.png. Вложенные папки можно. Скрытые файлы (имя с точки), а ещё Thumbs.db и desktop.ini, которые подкладывает Проводник, в плату не идут. Имена — только латиницей, без пробелов, и путь целиком не длиннее 63 символов.

Содержимое файлов для примеров:

// data/config.json
{
  "name": "teplitsa",
  "interval": 10,
  "led": true
}
<!-- data/index.html -->
<!doctype html>
<html lang="ru">
<head>
  <meta charset="utf-8">
  <meta name="viewport" content="width=device-width, initial-scale=1">
  <title>Моя плата</title>
  <link rel="stylesheet" href="/style.css">
</head>
<body>
  <h1>Привет от платы!</h1>
  <p>Эта страница лежит в памяти платы, в файле index.html.</p>
</body>
</html>
/* data/style.css */
body {
  font-family: sans-serif;
  max-width: 32rem;
  margin: 2rem auto;
  padding: 0 1rem;
}
h1 {
  color: #ff6a00;
}

Шаг 5. «Файлы» → «Залить»

Плата подключена кабелем с шага 2, выбран её COM-порт — нажмите «Файлы» ещё раз. Теперь программа спросит подтверждение и скажет, сколько файлов и какого объёма уйдёт в плату.

Окно Trema IDE «Залить файлы в плату?»: файлы в памяти платы заменятся содержимым папки data, 3 файла, 564 байт; «Скетч на плате не тронется»; «Разметка памяти должна быть та же, с которой залит скетч»; кнопки «Отмена» и «Залить»
Подтверждение: сколько файлов и что будет с платой.

Три строки окна — по делу:

  • «Файлы в памяти платы заменятся содержимым папки data» — раздел для файлов перезаписывается целиком. Всё, что там было, включая файлы, которые записал сам скетч (журнал, сохранённые настройки), исчезнет.
  • «Скетч на плате не тронется.» — программа лежит в другом месте памяти, её запись не касается.
  • «Разметка памяти должна быть та же, с которой залит скетч.» — то самое правило из шага 2.

Нажмите «Залить». Над консолью появится полоса «Заливка файлов» с часами и кнопкой «Остановить», а под ней — что сейчас происходит: «Готовлю файлы…», «Читаю разметку памяти платы», «Упаковываю папку data…», «Сверяю разметку памяти на плате», «Записываю файлы в плату…». Упаковывает файлы программа mklittlefs из пакета плат ESP32, а пишет в плату esptool — та же программа, что заливает скетч.

Окно Trema IDE во время заливки: в списке проекта папка data с config.json, index.html и style.css, над консолью полоса «Заливка файлов», 55 %, часы и кнопка «Остановить», под ней «Записываю файлы в плату… · COM16» и вывод esptool: Connected to ESP32 on COM16, Chip type ESP32-D0WDQ6
Заливка идёт: полоса хода над консолью, ниже — что делает программа записи.

Ближе к концу полоса дойдёт до 99 % и постоит там около 8 секунд: программа записи в это время дописывает и проверяет раздел. Это нормально, не останавливайте заливку.

Когда запись закончится, в консоли будет итог (для трёх файлов из примера, на схеме Default; время и порт у вас свои):

Консоль Trema IDE после записи: «Файлы залиты в плату.», «Код выхода: 0», «Время: 16984 мс», «Порт: COM16», «Залито 3 файла (564 байт) в раздел spiffs (1,4 МБ) по адресу 0x290000.»
Итог в консоли: файлы в плате.

Мы проверили это на настоящей ESP32 при Upload Speed 115200: три файла из примера записались за 17 секунд. Записывается весь раздел 1,4 МБ, поэтому для мелких файлов время почти не зависит от их размера; 600 КБ несжимаемых данных (фото, архивы) пишутся около минуты.

Последняя строка — самое важное: сколько файлов ушло, в какой раздел, его размер и где он лежит в памяти. У схемы Default адрес всегда 0x290000, у других схем свой. Ниже — подробный вывод программы записи, если понадобится разбираться. Если раздел в вашей разметке называется не spiffs, Trema IDE допишет в итог, как открыть его в скетче.

После записи плата перезапустится сама. Если вы входили в режим прошивки кнопкой BOOT, нажмите RESET (на некоторых платах — EN).

Пример 1. Прочитать файл и вывести в монитор

Первый скетч ничего не делает с Wi-Fi: открывает файловую систему, перечисляет файлы и печатает содержимое config.json. С него удобно начинать — сразу видно, дошли ли файлы.

// Читаем файлы из памяти ESP32 и печатаем их в монитор порта.
// Файлы лежат в папке data рядом со скетчем и заливаются в плату
// кнопкой «Файлы» в Trema IDE.
#include <LittleFS.h>

void setup() {
  Serial.begin(115200);
  delay(1000);  // даём монитору порта время открыться

  // false — не форматировать раздел, если он не читается: иначе
  // залитые файлы молча пропадут
  if (!LittleFS.begin(false)) {
    Serial.println("Память с файлами не открылась: залейте папку data кнопкой «Файлы»");
    return;
  }

  Serial.printf("Занято %u из %u байт\n",
                (unsigned)LittleFS.usedBytes(), (unsigned)LittleFS.totalBytes());

  // Список файлов в корне
  Serial.println("Файлы на плате:");
  File root = LittleFS.open("/");
  File file = root.openNextFile();
  while (file) {
    Serial.printf("  %s, %u байт\n", file.name(), (unsigned)file.size());
    file = root.openNextFile();
  }

  // Содержимое одного файла целиком
  File config = LittleFS.open("/config.json", "r");
  if (!config) {
    Serial.println("Нет файла /config.json");
    return;
  }
  Serial.println("Содержимое /config.json:");
  while (config.available()) {
    Serial.write(config.read());
  }
  config.close();
  Serial.println();
}

void loop() {
}

Если вы уже залили его в шаге 2, просто откройте монитор порта. Если нет — залейте кнопкой «Загрузить»: файлы при этом не трогаются, если в «Параметрах платы» не включено «Erase All Flash Before Sketch Upload». Оно стирает всю память, файлы тоже, и после такой заливки их надо залить заново.

В мониторе порта на 115200 сначала строка «Занято … из 1441792 байт» — второе число и есть размер раздела у схемы Default. Потом список: config.json, index.html, style.css с размерами, и сам текст config.json.

Монитор порта Trema IDE: «Плата перезапущена — программа пошла сначала.», «Занято 16384 из 1441792 байт», список config.json 58 байт, index.html 385 байт, style.css 121 байт и содержимое /config.json
Так выглядит монитор после сброса платы: файлы на месте.

Поменяйте в config.json число interval, нажмите «Файлы» ещё раз и сбросьте плату — монитор покажет новое значение, а скетч перезаливать не придётся.

В мониторе пусто — нажмите на плате RST или EN: скетч печатает всё один раз при запуске и мог закончить раньше, чем открылся монитор. У S3, C3 и C6, подключённых через USB самого чипа, ещё включите в «Параметрах платы» «USB CDC On Boot» → Enabled и залейте скетч заново: иначе плата печатает не в USB, а на выводы.

Обратите внимание на LittleFS.begin(false). С true плата при неудаче сама отформатирует раздел — удобно для нового устройства, но если вы просто ошиблись схемой, файлы исчезнут без предупреждения. С false скетч честно скажет, что память не открылась.

Пример 2. Сайт из файлов

Второй скетч подключается к Wi-Fi и раздаёт index.html и style.css из памяти платы. Впишите имя и пароль своей сети на 2,4 ГГц (на 5 ГГц ESP32 не подключается).

// Сайт на ESP32: страница index.html и оформление style.css лежат
// в памяти платы (папка data, кнопка «Файлы» в Trema IDE).
#include <WiFi.h>
#include <WebServer.h>
#include <LittleFS.h>

const char WIFI_SSID[] = "имя вашей сети";
const char WIFI_PASS[] = "пароль от сети";

WebServer server(80);

// Главная страница — файл /index.html
void sendIndex() {
  File page = LittleFS.open("/index.html", "r");
  if (!page) {
    server.send(500, "text/plain; charset=utf-8",
                "На плате нет index.html: залейте папку data кнопкой «Файлы»");
    return;
  }
  server.streamFile(page, "text/html");
  page.close();
}

void setup() {
  Serial.begin(115200);
  delay(1000);

  if (!LittleFS.begin(false)) {
    Serial.println("Память с файлами не открылась: залейте папку data кнопкой «Файлы»");
  }

  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PASS);
  Serial.print("Подключаюсь к Wi-Fi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print('.');
  }
  Serial.println();
  Serial.print("Откройте в браузере: http://");
  Serial.println(WiFi.localIP());

  server.on("/", HTTP_GET, sendIndex);   // адрес платы без файла — главная
  server.serveStatic("/", LittleFS, "/"); // остальное — файлы как есть: /style.css, картинки
  server.onNotFound([]() {
    server.send(404, "text/plain; charset=utf-8", "Такого файла на плате нет");
  });
  server.begin();
}

void loop() {
  server.handleClient();
}

Что здесь главное:

  • server.on("/", …) — когда браузер просит адрес платы без имени файла, отдаём index.html. Функция streamFile шлёт файл кусками и не держит его целиком в оперативной памяти.
  • server.serveStatic("/", LittleFS, "/") — всё остальное отдаётся прямо из памяти платы по имени: /style.css, картинки, скрипты. Тип файла сервер узнаёт по расширению.
  • onNotFound — ответ на адрес, которого нет.

Залейте скетч, откройте монитор порта и перейдите в браузере по адресу, который напишет плата. Хотите поменять страницу — правьте index.html, нажимайте «Файлы» и обновляйте страницу в браузере: скетч перезаливать не нужно. Как устроен такой сервер и где ещё можно держать страницу — в статье про веб-сервер на плате.

Что может пойти не так

Когда кнопка «Файлы» не может залить, над консолью появляется карточка: что случилось и что сделать. Кнопка «Подробнее на trema.ru» в ней ведёт сюда (у карточек про связь с платой — на страницу ошибок загрузки). Карточки с их заголовками:

Что пишет программаЧто на самом делеЧто сделать
«Файлы заливаются только по кабелю»В меню порта выбран адрес платы по Wi-Fi. По воздуху заливается только скетчПодключите плату кабелем, выберите её COM-порт вверху окна и нажмите «Файлы» ещё раз
«Не выбран порт платы»Плата не подключена или порт не выбранПодключите кабелем, выберите порт. Если порта нет вовсе — нужен драйвер или кабель «с данными»
«В выбранной разметке памяти нет места под файлы»В «Параметрах платы» стоит схема без раздела для файлов, например No FS или схема с ffatВыберите схему со SPIFFS, например «Default 4MB with spiffs». Залейте скетч кнопкой «Загрузить», потом нажмите «Файлы»
«В partitions.csv проекта нет места под файлы»В папке проекта лежит свой файл partitions.csv — он главнее меню, — а раздела для файлов в нём нетПроще всего удалить свой partitions.csv из папки проекта — тогда схема берётся из меню. Или замените его готовым файлом ниже. Потом скетч кнопкой «Загрузить» и снова «Файлы»
«В разметке этой платы нет места под файлы»Разметку задаёт сама плата своим partitions.csv, и раздела для файлов в нём нетПоложите в папку проекта готовый partitions.csv из-под этой таблицы: он главнее. Скетч заново — и «Файлы»
«Скетч на плате залит с другой разметкой памяти»Перед записью Trema IDE читает разметку с самой платы. Раздел для файлов там не на том месте, что в выбранной схеме: запись задела бы программуПлата не тронута. Залейте скетч кнопкой «Загрузить» с нужной схемой, потом нажмите «Файлы»
«Файлы не помещаются в память платы»Файлы с запасом на служебные записи файловой системы не входят в раздел, а каждый файл занимает целое число блоков по 4 КБ. Карточка скажет, сколько займут файлы и сколько есть местаУберите что-нибудь из папки data (большие картинки, видео), объедините мелкие файлы или выберите в «Параметрах платы» схему, где под файлы больше места
«Переименуйте файлы латиницей»В имени файла или папки русские буквы или значки — скетч такой файл не откроетПереименуйте латиницей, без пробелов: «кот.png» → «cat.png». Программа перечислит, какие именно
«Слишком длинные имена файлов»Путь к файлу, вместе с папками и косыми чертами, длиннее 63 символовСократите имена или уберите лишнюю вложенность папок
«Не удалось подготовить пакет платы ESP32»Пакет плат ещё не установлен, а интернета нетПодключите компьютер к сети и нажмите «Файлы» ещё раз — пакет скачается сам. Не помогло — переустановите его в разделе «Платы»
«Не хватает программы для заливки файлов»В пакете платы нет программы упаковки или записи (mklittlefs, esptool)Переустановите пакет плат ESP32 в разделе «Платы»
«Переведите плату в режим прошивки кнопкой BOOT»Плата S2 или S3 подключена через USB самого чипа, в «Параметрах платы» выбран Upload Mode «USB-OTG CDC (TinyUSB)» (у S2 — «Internal USB»), и сама в режим записи она не вошлаЗажмите BOOT, нажмите и отпустите RESET, отпустите BOOT — и снова «Файлы»
«Плата ESP не входит в режим прошивки»Плата не ответила программе записи: не тот порт, кабель только для зарядки или автосброс не сработал. У C3, C6 и S3 в обычном режиме вместо карточки про BOOT будет этаЗажмите BOOT в момент начала записи и держите, пока она не пойдёт. Или: зажмите BOOT, нажмите и отпустите RESET, отпустите BOOT. Проверьте кабель
«Связь с платой ESP обрывается во время прошивки»Плата откликнулась, но передача рвётся: кабель, разъём или питаниеВозьмите короткий кабель, воткните в порт самого компьютера, не в хаб. В «Параметрах платы» поставьте Upload Speed пониже, например 115200
«Файлы не записались в плату»Запись не прошла, а причину программа не узналаПроверьте кабель и порт, отключите от платы лишние провода и попробуйте ещё раз. Что ответила программа записи — в консоли
«Не удалось упаковать папку data»Программа упаковки остановилась с ошибкой. Чаще всего файл из data открыт в другой программеЗакройте файлы из data в других программах (редактор картинок, браузер) и попробуйте ещё раз
«Эта плата не хранит файлы»Вверху окна выбрана не ESP32 и не ESP8266Проверьте, какая плата выбрана: кнопка «Файлы» работает только с ними
«Разметка памяти платы не читается»Ошибка в своём partitions.csv в папке проекта или повреждён пакет платыПроверьте строки partitions.csv; если своего файла нет — переустановите пакет плат ESP32

Например, так выглядит карточка, если скетч залит со схемой Default, а в «Параметрах платы» потом выбрали Huge APP: Trema IDE прочитала разметку с платы, увидела, что раздел для файлов лежит в другом месте, и ничего не записала.

Карточка над консолью Trema IDE: «Заливка файлов», «Скетч на плате залит с другой разметкой памяти», начало объяснения «Раздел для файлов на плате лежит не там, где в выбранной сейчас разметке…», строка «на плате раздел для файлов «spiffs» по адресу 0x290000, 1,4 МБ выбрано сейчас — 0x310000, 896 КБ» и кнопка «Подробнее на trema.ru»
Плата не тронута: залейте скетч с нужной схемой, потом файлы.

Если «Загрузить» или «Файлы» обрываются с «Unable to verify flash chip connection» или связь пропадает посреди записи, поставьте в «Параметрах платы» «Upload Speed» → 115200 (по умолчанию там 921600) и попробуйте снова. Такое мы видели на плате с CH340.

А если заливка прошла, но скетч пишет «Память с файлами не открылась», чаще всего скетч залит с другой схемой, чем файлы, или в нём SPIFFS.begin() вместо LittleFS.begin(). Если в скетче было SPIFFS.begin(true) или LittleFS.begin(true), раздел мог уже отформатироваться — тогда исправьте скетч и залейте файлы заново.

Файлы пропали после заливки скетча — проверьте «Параметры платы»: если там «Erase All Flash Before Sketch Upload» → Enabled, заливка скетча стирает всю память. Поставьте Disabled и залейте файлы заново.

Если плата сама задаёт разметку без места под файлы или в вашем partitions.csv нет такого раздела, положите в папку проекта этот файл под именем partitions.csv — та же разметка, что у схемы Default (подходит платам с 4 МБ и больше):

# Name,   Type, SubType, Offset,  Size, Flags
nvs,      data, nvs,     0x9000,  0x5000,
otadata,  data, ota,     0xe000,  0x2000,
app0,     app,  ota_0,   0x10000, 0x140000,
app1,     app,  ota_1,   0x150000,0x140000,
spiffs,   data, spiffs,  0x290000,0x160000,
coredump, data, coredump,0x3F0000,0x10000,

Раздел для файлов в нём — строка spiffs, 1,4 МБ с адреса 0x290000. После этого залейте скетч кнопкой «Загрузить», потом файлы.

В меню порта (кнопка с COM-портом вверху окна) у плат ESP32 и ESP8266 есть строка «Файлы на плате (папка data)» — она тоже открывает эту инструкцию.

Меню порта Trema IDE: порты COM4 и COM5, группа «По Wi-Fi» и строки «Искать платы в сети», «Указать адрес платы…», «Как заливать по Wi-Fi» и «Файлы на плате (папка data)»
Строка «Файлы на плате (папка data)» в меню порта.

Частые вопросы

Можно ли называть файлы и папки в data по-русски?

Нет. Имя с русскими буквами попадает в память платы в другой кодировке, и скетч такой файл не откроет, поэтому Trema IDE откажется заливать и назовёт эти файлы. Пишите латиницей, без пробелов, а путь целиком, вместе с папками и косыми чертами, — не длиннее 63 символов.

Сколько файлов поместится в память ESP32?

Сколько даёт схема памяти: у Default 4MB with spiffs под файлы 1,4 МБ, у No OTA (1MB APP/3MB SPIFFS) — 2,9 МБ. Но считать надо блоками: память делится на блоки по 4 КБ, и каждый файл больше 256 байт занимает их целиком. Сто файлов по 300 байт займут не 30 КБ, а около 400. Если не входит, Trema IDE скажет, сколько нужно и сколько есть.

Сотрёт ли заливка файлов мой скетч?

Нет. Кнопка «Файлы» пишет только раздел для файлов, а программа лежит в другом месте памяти и остаётся как была. Скетч можно заливать отдельно, кнопкой «Загрузить», — файлы он тоже не трогает, если в «Параметрах платы» не включено «Erase All Flash Before Sketch Upload». Оно стирает всю память, файлы тоже, и после такой заливки их надо залить заново.

Пропадут ли файлы, которые записал сам скетч?

Да. Раздел для файлов заменяется целиком содержимым папки data: журнал, настройки и всё, что программа сохранила на плату сама, исчезнет. Если такие файлы нужны, сначала выведите их в монитор порта или отдайте на страницу и сохраните на компьютере.

Можно ли залить файлы по Wi-Fi?

В Trema IDE — нет, только по кабелю. По Wi-Fi заливается скетч, а для файлов выберите COM-порт платы. Если выбран адрес по Wi-Fi, программа скажет «Файлы заливаются только по кабелю» и ничего не тронет.

Как это делается в Arduino IDE?

В Arduino IDE 1.8 был отдельный Java-плагин ESP32 Sketch Data Upload: его скачивали, клали в папку tools и перезапускали программу. В Arduino IDE 2 старые плагины не работают, встроенной команды нет: ставят плагин arduino-littlefs-upload и вызывают команду «Upload LittleFS to Pico/ESP8266/ESP32» в палитре Ctrl+Shift+P. В Trema IDE начиная с версии 1.10.13 это кнопка «Файлы» на панели, рядом с «Загрузить», плагин не нужен. Проект из Arduino IDE с папкой data рядом со скетчем открывается в Trema IDE как есть: папка та же, файловая система та же — LittleFS.

Почему раздел называется spiffs, если файлы в LittleFS?

Имя осталось от старой файловой системы SPIFFS, которой раздел пользовался раньше. Схемы памяти в ядре ESP32 так его и называют, а LittleFS.begin() по умолчанию ищет раздел именно с этим именем. Внутри — LittleFS.

ESP32-S3 или C3 не входит в режим прошивки. Что делать?

У плат с USB прямо на чипе так бывает, когда скетч занял USB. Зажмите на плате BOOT, нажмите и отпустите RESET, затем отпустите BOOT — и нажмите «Файлы» ещё раз. У S2 и S3 с Upload Mode «USB-OTG CDC (TinyUSB)» (у S2 — «Internal USB») Trema IDE подскажет это карточкой «Переведите плату в режим прошивки кнопкой BOOT». У C3, C6 и у S3 в обычном режиме карточка будет «Плата ESP не входит в режим прошивки» — совет тот же.

Дальше по теме

Файлы на плате в Trema IDE

Папка data рядом со скетчем и кнопка «Файлы» на панели — без плагинов и ручной возни с программами записи. Схему памяти программа сверяет с платой сама, а ошибки объясняет по-русски.