Raspberry Pi Pico в Arduino IDE

Raspberry Pi Pico вместо Uno: что меняется

• Выводы работают от 3,3 В, и 5 В на них подавать нельзя.
• В скетче вывод называют номером GP: digitalWrite(15, HIGH) включает GP15, а не ножку номер 15.
• Serial идёт через USB, а выводы GP0 и GP1 — это Serial1.
• Аналоговых входов три, A0–A2. analogRead() отдаёт 0–1023, как на Uno, но верх шкалы — 3,3 В.
• Первую программу загружают с кнопкой BOOTSEL, дальше — через COM-порт, как на Uno.
• Blink занимает 54 КБ, а не 1 КБ. Это нормально: флеш-памяти у Pico 2 МБ, у Uno — 32 КБ.

Какая у вас плата: Raspberry Pi Pico, Pico W или Pico 2

Оригинальных плат четыре. Pico — первая, на RP2040. Pico W — она же с Wi-Fi и Bluetooth: её узнают по металлическому экрану и антенне у нижнего края. Pico 2 и Pico 2 W — то же самое на новом чипе RP2350. Буква H в названии (Pico H, Pico WH) значит, что ножки уже впаяны и есть разъём для отладчика; у Pico 2 такие платы называются «with headers». Pico от Pico 2 отличают по надписи на чипе: RP2040 или RP2350.

У нас в магазине есть Pico, Pico W и Pico 2.

RP2040 или RP2350: что изменилось в Pico 2

В Pico 2 стоит RP2350: ядра Cortex-M33 вместо M0+, 520 КБ оперативной памяти вместо 264 и 4 МБ флеш-памяти вместо 2. Частота по умолчанию — 150 МГц, ниже, чем у Pico в Arduino, но ядра M33 за такт успевают больше и считают дробные числа аппаратно, так что на деле Pico 2 быстрее. Необычное в чипе — второй комплект ядер на RISC-V: в Arduino IDE архитектура выбирается пунктом CPU Architecture, ARM или RISC-V, и один и тот же скетч собирается под обе. Разводка у Pico 2 та же, что у Pico, так что схемы и платы расширения подходят к обеим.

У первых партий RP2350 был изъян: вход с внутренней подтяжкой к земле мог «залипать» на 2,2 В, и кнопка, подключённая к 3,3 В, читалась неверно. В чипах новой ревизии A4 его исправили, но платы со старыми ещё продаются. Подключайте кнопки к земле и читайте их с INPUT_PULLUP — так работает на любой ревизии.

RP2040-Zero, YD-RP2040 и другие платы на RP2040

Кроме оригинальных Pico, на RP2040 делают десятки плат: крошечную Waveshare RP2040-Zero с разъёмом USB-C, YD-RP2040 от VCC-GND с флеш-памятью до 16 МБ, Seeed XIAO RP2040 и Adafruit Feather. Чип у них тот же, но светодиоды, кнопки и объём памяти свои, поэтому выбирайте в меню пункт своей платы, а не «Raspberry Pi Pico». У RP2040-Zero обычного светодиода нет вовсе — только цветной WS2812 на GP16, и Blink с LED_BUILTIN для неё не соберётся. Вот скетч для цветного; ему нужна библиотека Adafruit NeoPixel из менеджера библиотек:

// Цветной светодиод Waveshare RP2040-Zero: WS2812 на GP16.
// Обычного светодиода у этой платы нет, поэтому Blink с LED_BUILTIN
// для неё не соберётся. Нужна библиотека Adafruit NeoPixel.
#include <Adafruit_NeoPixel.h>

const int RGB_PIN = 16;
const int BRIGHTNESS = 40;   // 0–255: на полной яркости светодиод слепит

// Если красный горит зелёным, замените NEO_GRB на NEO_RGB:
// у разных партий плат светодиоды бывают с разным порядком цветов.
Adafruit_NeoPixel rgb(1, RGB_PIN, NEO_GRB + NEO_KHZ800);

void showColor(const char *name, int r, int g, int b) {
  rgb.setPixelColor(0, rgb.Color(r, g, b));
  rgb.show();
  Serial.println(name);
  delay(1000);
}

void setup() {
  Serial.begin(115200);
  rgb.begin();
}

void loop() {
  showColor("красный", BRIGHTNESS, 0, 0);
  showColor("зелёный", 0, BRIGHTNESS, 0);
  showColor("синий", 0, 0, BRIGHTNESS);
  showColor("погашен", 0, 0, 0);
}

Arduino или MicroPython

Pico часто продают как плату для MicroPython, и в школах её нередко изучают на Python. Программировать её можно и так и так:

Переход в любую сторону — это просто новая прошивка. На плате с MicroPython свой COM-порт, и первый скетч из Arduino надёжнее загрузить через кнопку BOOTSEL — как это делается, рассказано в разделе «Первая прошивка». Вернуться на MicroPython так же просто: держите BOOTSEL, подключите плату и скопируйте на появившийся диск файл MicroPython с сайта Raspberry Pi.

Первая прошивка: кнопка BOOTSEL и порт «UF2 Board»

Загрузчик Pico зашит в сам чип, и испортить его нельзя. Если держать кнопку BOOTSEL в момент подключения кабеля, плата появится в компьютере как флешка RPI-RP2 (у Pico 2 — RP2350). Файл прошивки с расширением .uf2, скопированный на этот диск, записывается в плату, и она сразу перезапускается с новой программой. Arduino IDE делает это сама — нужно только правильно выбрать порт. Каким он будет, зависит от того, что сейчас на плате:

По шагам для новой платы:

1. Нажмите и держите BOOTSEL, подключите плату кабелем к компьютеру и отпустите кнопку — появится диск RPI-RP2.
2. В меню «Инструменты → Плата» выберите свою плату, например «Raspberry Pi Pico».
3. В «Инструменты → Порт» выберите «UF2 Board» и нажмите «Загрузить».
4. Когда в окне вывода внизу появятся строки «Flashing» и «Wrote … bytes», плата перезапустится с вашей программой, а в списке портов появится её COM-порт. Дальше загружайте через него — кнопка больше не нужна.

// Маячок для Raspberry Pi Pico, Pico W, Pico 2 и Pico 2 W.
// У Pico и Pico 2 светодиод на GP25, у Pico W и Pico 2 W — на радиочипе,
// но LED_BUILTIN пакет сам направляет куда нужно.
// У RP2040-Zero простого светодиода нет: для неё — скетч с цветным.

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
  digitalWrite(LED_BUILTIN, HIGH);   // зажгли
  delay(100);
  digitalWrite(LED_BUILTIN, LOW);    // погасили
  delay(900);
}

На Pico этот скетч занимает 54 КБ из 2 МБ — больше, чем на Uno, потому что в каждую программу входят драйвер USB и часть библиотек чипа. На Pico W он вырастает до 313 КБ: светодиод там подключён к радиочипу, и, чтобы им мигать, в программу добавляется драйвер радио вместе с его прошивкой.

Прошить вручную: файл .uf2 на диск RPI-RP2

Если порта «UF2 Board» в списке нет или загрузка не находит диск, файл прошивки можно скопировать вручную. В Arduino IDE выберите «Скетч → Экспортировать скомпилированный бинарный файл»: в папке скетча появится папка build, в ней — папка с названием платы, а там файл с расширением .uf2. Trema IDE после сборки пишет путь к файлу прошивки, и .uf2 лежит в той же папке. Переведите плату в режим BOOTSEL и перетащите файл на диск RPI-RP2 — плата сама перезапустится.

Так же можно стереть плату целиком, если она ведёт себя странно: Raspberry Pi выкладывает файл nuke_universal.uf2, который очищает флеш-память. После него на плате ничего нет, и при включении она сама открывается как диск.

Wi-Fi и Bluetooth на Raspberry Pi Pico W и Pico 2 W

Для Wi-Fi в меню «Инструменты → Плата» выберите «Raspberry Pi Pico W» (или «Raspberry Pi Pico 2W»). Если оставить «Raspberry Pi Pico», скетч с Wi-Fi соберётся без единой ошибки, но вместо радио в него попадёт пустой драйвер: плата прошьётся и будет бесконечно ждать подключения к сети. Wi-Fi у Pico W только на 2,4 ГГц: сеть 5 ГГц плата не увидит.

Ниже — небольшая веб-страница. Впишите в начало скетча имя и пароль своей сети Wi-Fi, загрузите его и откройте монитор порта: плата напечатает свой адрес. Наберите его в браузере телефона или компьютера, подключённого к той же сети, и включайте светодиод кнопками на странице.

// Веб-страница на Pico W: температура чипа и кнопки для светодиода.
// В меню нужна плата «Raspberry Pi Pico W» или «Raspberry Pi Pico 2W».
// С пунктом для обычного Pico скетч соберётся, но сеть не появится:
// в этом пункте нет драйвера радио. Wi-Fi у Pico W только 2,4 ГГц.
#include <WiFi.h>
#include <WebServer.h>

const char *SSID = "ИмяСети";     // имя вашей сети Wi-Fi
const char *PASS = "пароль";       // и пароль от неё

WebServer server(80);
bool ledOn = false;

void showPage() {
  String page = "<!doctype html><meta charset='utf-8'>";
  page += "<meta name='viewport' content='width=device-width'>";
  page += "<h1>Pico W</h1><p>Температура чипа: ";
  page += String(analogReadTemp(), 1);
  page += " °C</p><p>Светодиод ";
  page += ledOn ? "горит" : "погашен";
  page += "</p><p><a href='/on'>Зажечь</a> &nbsp; <a href='/off'>Погасить</a></p>";
  server.send(200, "text/html", page);
}

void setLed(bool on) {
  ledOn = on;
  digitalWrite(LED_BUILTIN, on ? HIGH : LOW);
  server.sendHeader("Location", "/");   // вернуться на главную страницу
  server.send(303);
}

void setup() {
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  WiFi.begin(SSID, PASS);
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print(".");
    delay(500);
  }
  Serial.println();
  Serial.print("Откройте в браузере адрес ");
  Serial.println(WiFi.localIP());
  server.on("/", showPage);
  server.on("/on", []() { setLed(true); });
  server.on("/off", []() { setLed(false); });
  server.begin();
}

void loop() {
  server.handleClient();
}

Bluetooth по умолчанию выключен — так он не занимает память. Включается он в меню «Инструменты → IP/Bluetooth Stack» пунктом «IPv4 + Bluetooth»: Pico W умеет и классический Bluetooth, и Bluetooth LE. Подробнее о сети — в статье про Wi-Fi в Arduino.

Два ядра: setup1() и loop1()

У RP2040 и RP2350 по два ядра, и занять второе в пакете Philhower просто: всё, что написано в setup() и loop(), работает на первом ядре, а в setup1() и loop1() — на втором. Так одно ядро может опрашивать датчик без остановки, пока второе рисует на экране или отвечает в сети. Передавать числа между ядрами удобно через очередь rp2040.fifo:

// Два ядра: setup() и loop() работают на первом, setup1() и loop1() — на втором.
// Второе ядро без остановки считает среднее по аналоговому входу GP26,
// первое мигает светодиодом и печатает результат, когда он готов.
// Данные передаются через очередь rp2040.fifo — так ядра не мешают друг другу.

const int SENSOR_PIN = 26;   // GP26, он же A0: 0–3,3 В
bool ledOn = false;

void setup() {
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
}

void loop() {
  ledOn = !ledOn;
  digitalWrite(LED_BUILTIN, ledOn ? HIGH : LOW);
  uint32_t average;
  if (rp2040.fifo.pop_nb(&average)) {   // пришло новое число со второго ядра
    Serial.print("GP26, среднее из 1000 замеров: ");
    Serial.println(average);
  }
  delay(500);
}

void setup1() {
  analogReadResolution(12);   // 0–4095 вместо 0–1023
}

void loop1() {
  uint32_t sum = 0;
  for (int i = 0; i < 1000; i++) {
    sum += analogRead(SENSOR_PIN);
  }
  rp2040.fifo.push_nb(sum / 1000);   // не ждём, если первое ядро не забрало прошлое
  delay(1000);
}

Блоки PIO и USB

Ещё одна особенность чипа — блоки PIO: маленькие независимые процессоры для работы с выводами. На них пакет делает дополнительные UART, сервоприводы и звук, а библиотека Adafruit NeoPixel — управление светодиодными лентами, не нагружая основные ядра. А с библиотеками Keyboard и Mouse компьютер видит Pico как USB-клавиатуру или мышь.

Какой чип и на какой частоте: проверочный скетч

Скетч ниже печатает, какой чип стоит на плате, на какой частоте он работает, есть ли радио и сколько свободно памяти. Pico по умолчанию работает на 200 МГц: паспортные 133 МГц Raspberry Pi в 2025 году официально подняла до 200, и пакет сразу это использует. Частоту можно поменять в меню CPU Speed.

// Что за плата: какой чип, на какой частоте работает, есть ли радио.
// Печатает раз в 5 секунд в монитор порта (скорость не важна, порт — USB).

void setup() {
  Serial.begin(115200);
}

void loop() {
#if defined(PICO_RP2350)
#if defined(__riscv)
  Serial.println("Чип: RP2350 (Pico 2), ядра RISC-V Hazard3");
#else
  Serial.println("Чип: RP2350 (Pico 2), ядра ARM Cortex-M33");
#endif
#else
  Serial.println("Чип: RP2040 (Pico), ядра ARM Cortex-M0+");
#endif
  Serial.print("Частота: ");
  Serial.print(rp2040.f_cpu() / 1000000);
  Serial.println(" МГц");
  Serial.print("Радиочип Wi-Fi и Bluetooth: ");
  Serial.println(rp2040.isPicoW() ? "есть" : "нет");
  Serial.print("Температура чипа: ");
  Serial.print(analogReadTemp(), 1);   // встроенный датчик, точность — пара градусов
  Serial.println(" °C");
  Serial.print("Свободно оперативной памяти: ");
  Serial.print(rp2040.getFreeHeap() / 1024);
  Serial.println(" КБ");
  Serial.print("Номер чипа: ");
  Serial.println(rp2040.getChipID());
  Serial.println();
  delay(5000);
}

Ошибки прошивки и сборки

Общие беды загрузки — кабель без линий данных, порт занят другой программой — разобраны в статье про ошибки загрузки.

Raspberry Pi Pico или ESP32

Обе платы недорогие и быстрые, а берут их для разного. ESP32 — плата для сети: Wi-Fi есть почти у всех её вариантов, а примеров для умного дома, MQTT и Telegram-ботов под неё больше всего. Pico берут за блоки PIO, два ядра без фоновых задач радио, USB прямо в чипе, через который плата становится клавиатурой или мышью, и загрузчик в самом чипе, который не испортить никаким скетчем. Нужна сеть — берите ESP32 или Pico W, нужны точные сигналы, много выводов и USB — Pico.